;****************************************************************************
;Filename:		gridstart.asm
;Author:		Pete Griffiths	
;Date:  		23/05/2008	
;Version:		1.0.6 
;Description:  	Race Track F1 style grid start controller	
;Information:		http://picprojects.org.uk/projects/	 
;****************************************************************************
;Revision History
;****************************************************************************
                
                #include p16f684.inc          	; processor specific variable definitions

                __CONFIG   _CP_OFF & _CPD_OFF & _BOD_ON  & _MCLRE_ON & _WDT_ON & _PWRTE_ON & _INTRC_OSC_NOCLKOUT  
                
                errorlevel -302     ; suppress banksel warning messages


;****************************************************************************
;Defines
;****************************************************************************
#define	BANK0		bcf	STATUS,RP0	;Select BANK0
#define	BANK1		bsf	STATUS,RP0	;Select BANK1

startSwitch	equ           2             	; RA2 start switch input (schmitt trigger input)
driveMode    	equ           0	; RA0 drive mode 0=constant, 1= PWM (for LEDs)
brightPot    	equ           1	; AN1 analogue input for adjusting LED brightness by PWM
distDrive	equ	4	; RA4 0 = PWM with constant outputs drive
			;     1 = PWM with multiplexed output drive


light1        equ           0
light2        equ           1
light3        equ           2
light4        equ           3
light5        equ           4

; flag bits
oneSecond     equ           0             ; set every second in Int Handler, cleared by state code
brightAdj	equ	1             ; used by display driver code
tmr2out	equ	2             ; state machine runs each time this flag set (every 4mS)
holdOut	equ	3             ; random hold time out flag



;****************************************************************************
; Variables in GPR 
;****************************************************************************

              cblock        0x70          ; This GPR range is common to all banks
               w_temp
               status_temp
               flags
               state
               tick
	 countDown
	 holdLo
	 holdHi
	 portMirror
	 driveMask
	 brightLevel

              endc
;****************************************************************************
;Reset Vector
;****************************************************************************
              org            0x000           ; reset vector
	nop	                 ; 
	goto    Init                   ; run start up code



;****************************************************************************
;Interrupt Vector
;****************************************************************************
              org           0x004             ; interrupt vector location
Isr           movwf         w_temp
              swapf         STATUS,W
              clrf          STATUS
              movwf         status_temp
	clrwdt	                  ; clear Watchdog timer
              
              btfsc         PIR1, TMR2IF
              call          _timer2IH
	btfsc	INTCON, T0IF
	call	_displayIH

              swapf         status_temp,W
              movwf         STATUS
              swapf         w_temp,F
              swapf         w_temp,W
              retfie

;-----------------------------------------------------

_timer2IH     bcf	PIR1, TMR2IF
	bsf	flags, tmr2out
	
	clrz
	btfss	flags, holdOut
	decf	holdLo,F
	skpnz
	decf	holdHi,F
	skpnz
	bsf	flags, holdOut

	decfsz        tick,F
              return

              movlw         .250
              movwf         tick
              bsf           flags, oneSecond
	decf	countDown,F
              return
;-----------------------------------------------------
;

_displayIH	bcf	INTCON, T0IF                ; clear TMR0 Interrupt Flag
	btfss	PORTA, driveMode            ; Test drive mode input
	goto	_staticDrive                ; if jumper set, do static drive
	nop
	movlw	1<<brightAdj                ; toggle brightAdj flag bit
	xorwf	flags,F
	btfsc	flags, brightAdj            ; skip next if flag bit clear
	goto	_activePhase                ; else run the activePhase code

	movfw	brightLevel                 ; load TMR0 with brightness level from ADC
	movwf	TMR0                        ; to produce a PWM effect on the LED output
              clrf          PORTC                       ; turn off all outputs
	return

_activePhase	comf	brightLevel,W
	movwf	TMR0
	movfw	portMirror                  ; load portMirror into W
	btfsc	PORTA, distDrive	; select PWM mode static or multiplexed
	andwf	driveMask,W                 ; select single output bit for multiplexed drive
	movwf	PORTC                       ; write to PORTC
	clrc                                      ; 
	rrf	driveMask,F                 ; shift driveMask one bit
	skpnc                                     ; test if a '1' shifted into carry              
	bsf	driveMask, light5           ; if it did, reset mask to point to light5


	movfw	ADRESH		; read last ADC conversion into W reg
	bsf	ADCON0, GO_DONE	; start new conversion
	subwf	brightLevel,W		; compare current ADC value with current level
	skpnz			; if they're the same, no change needed
	return	
	movlw	.1		; otherwise add or subtract 1 from current level
	skpnc			; so it moves towards the current ADC value.
	movlw	-.1		; This prevents odd spurious values from causing
	addwf	brightLevel,F		; flashing of the LED display.
	return
	
_staticDrive	movfw	portMirror		; All outputs are active
	movwf	PORTC		; for driving relays or other output device
	return


;****************************************************************************
;Initialization
;****************************************************************************
Init          clrf          PCLATH
      	bcf	STATUS, RP0

              movlw         1<<CM2 | 1<<CM1 | 1<<CM0
              movwf         CMCON0
			
              clrf          PORTC         
				
	BANK1
	clrf	OPTION_REG     
	;bsf	OPTION_REG, PS0
		
              movlw         (1<<brightPot)
              movwf         ANSEL         
	
              movlw         !(1<<light5 | 1<<light4 | 1<<light3 | 1<<light2 | 1<<light1)
              movwf         TRISC
   	
              movlw         0xFF
              movwf         TRISA
              
              movlw         1<<driveMode | 1<<distDrive
              movwf         WPUA
              
              movlw         .250          ;set timer2 for int' period of 4mS with 4Mhz clock
              movwf         PR2              
              bsf           PIE1, TMR2IE

	movlw	b'01010000'
	movwf	ADCON1

              BANK0

	bsf	T1CON, TMR1ON
	bsf	T1CON, T1CKPS1

              movlw         b'01111100'
              movwf         T2CON
	
	movlw	b'00000111'
	movwf	ADCON0
   	
              ; clear GPR from 0x20 to 0x7F
              movlw         0x20
              movwf         FSR
_clearnext    clrf          INDF
              incf          FSR,F
              btfss         FSR,7
              goto          _clearnext
              
              bsf	driveMask, light5

              bsf           INTCON, PEIE
	bsf	INTCON, T0IE
              bsf           INTCON, GIE


	movlw	(1<<light5 | 1<<light4 | 1<<light3 | 1<<light2 | 1<<light1)
	movwf	portMirror
	movlw	.2
	movwf	countDown
	movf	countDown,F
	skpz
	goto	$-2
		
	; Diagnostic test,
	; outputs show 10101 if switch input is detected as active (switch pressed)
	; won't clear until switch input is inactive
_swClosed	btfsc	PORTA, startSwitch	; is StartSwitch input active?
	goto	_swOpen
	movlw	(1<<light5 | 1<<light3 | 1<<light1 )
	movwf	portMirror
	goto	_swClosed

		
_swOpen	movlw	(1<<light4 | 1<<light2 )
	movwf	portMirror
	movlw	.8
	movwf	countDown
_powerWait	movf	countDown,F
	skpnz
	goto	_powerDone
	btfsc	PORTA, startSwitch
	goto	_powerWait
	
_powerDone	btfss	PORTA, startSwitch
	goto	$-1

	clrf	portMirror

;****************************************************************************
; State machine
;****************************************************************************

_idle	btfss	flags, tmr2out              ; flag set every 4mS
	goto	_idle
	bcf	flags, tmr2out
	call	_selectState
	goto	_idle


_selectState	movfw         state
              addwf         PCL,F
              goto          _waitSwPress
              goto          _waitSwRel
              goto          _initCount
              goto          _countDown
              goto          _setRandHold
	goto	_lightsOut

              
;-----------------------------------------------------
_waitSwPress  btfsc         PORTA, startSwitch
              return
	incf          state,F
	return
;-----------------------------------------------------
_waitSwRel    btfss         PORTA, startSwitch
              return       

	bsf	flags, holdOut              ; stop hold timer code from running

	movfw	TMR1H                       ; get 'random' value from TMR1
	movwf	holdLo
              andlw         0x07                        ; mask off unwanted bits
              movwf	holdHi                      ; save in holdHi var
              andlw         b'00000110'                 ; if holdHi < 2 
              skpnz                                     ; then set == 2
              bsf           holdHi,1  
              
              incf          state,F       
	return
;-----------------------------------------------------
_initCount    bsf           portMirror, light1          ; turn on light1
              movlw         .250                        ; initialise 1 second timer
              movwf         tick
              bcf           flags, oneSecond

              incf          state,F
              return
;-----------------------------------------------------
_countDown    btfss         flags, oneSecond            ; wait on second timeout
              return       
  	bcf	flags, oneSecond            ; reset oneSecond flag
	setc                                      
              rlf           portMirror,F
              btfss         portMirror, light5
              return

              incf          state,F
              return

;-----------------------------------------------------
_setRandHold  btfss	flags, oneSecond
	return
                  

	incf	state,F
	bcf	flags, holdOut
	return
              
;-----------------------------------------------------
_lightsOut	btfss	flags, holdOut
	return
	clrf	portMirror
	clrf	state
	return

	dt "http://picprojects.org.uk "
	dt "Race Start Controller V2 "
	dt "(c) Pete Griffiths 2008 "
	dt "F/W Rev 1.0.6 "


              end