;**********************************************************************
;                                                                     *
;    Filename:      sirc10fv10rem.asm                                 *
;    Date:          06-02-2010                                        *
;    File Version:                                                    *
;                                                                     *
;    Author:        Pete Griffiths                                    *
;    Company:       Picprojects                                       *
;                                                                     *
;**********************************************************************
;    Copyright 2010 Pete Griffiths
;
;    This program is free software: you can redistribute it and/or
;    modify it under the terms of the GNU General Public License as 
;    published by the Free Software Foundation, either version 3 of 
;    the License, or any later version.
;
;    This program is distributed in the hope that it will be useful,
;    but WITHOUT ANY WARRANTY; without even the implied warranty of
;    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;    GNU General Public License for more details.
;
;    You should have received a copy of the GNU General Public License
;    along with this program. If not, see http://www.gnu.org/licenses/
;
;**********************************************************************
;                                                                     *
;    Files Required: P10F200.INC                                      *
;                                                                     *
;**********************************************************************
;                                                                     *
;    Notes:                                                           *
;            Web release: 12 bit SIRC mini IR Transmitter             *
;            see http://picprojects.org.uk/projects for full details  *
;                                                                     *
;    See PIC10F20x datasheet:                                         *
;         http://ww1.microchip.com/downloads/en/DeviceDoc/41239D.pdf  *
;                                                                     *
;**********************************************************************


                ifdef     __10F200
                list      p=10F200            ; list directive to define processor
                #include <p10F200.inc>        ; processor specific variable definitions
                endif

                ifdef     __10F202
                list      p=10F202            ; list directive to define processor
                #include <p10F202.inc>        ; processor specific variable definitions
                endif

                __CONFIG   _MCLRE_OFF & _CP_OFF & _WDT_OFF 


;*******************************************************************************************
; USER CONFIGURABLE SWITCH SIRC CODES
; These are the SIRC device/command codes that are transmitted
; Transmission comprises 7 bit command and 5 bit device code
;
C.device.id     equ             .1              ; SIRC Device ID [0-31]

                                                ; SIRC Command code [0-127]
                                                ; to disable a switch set value to .255
C.cmd.S1        equ             .8              ; command sent on Switch 1 
C.cmd.S2        equ             .1              ; command sent on Switch 2
C.cmd.S3        equ             .0              ; command sent on Switch 3
;
;  Defaults above are for Sony TV remote.
;  See http://www.sbprojects.com/knowledge/ir/sirc.htm for additional codes and SIRC FAQ.
;******************************************************************************************* 

; CONSTANT for number of bits to transmit - don't change
Ccmd.bit.length equ             7 ; SIRC command bit length
Cdev.bit.length equ             5 ; SIRC device bit length


;***** VARIABLE DEFINITIONS
; GPR starts at 0x0C for 10F202 / 10F206
; GPR starts at 0x10 for 10F200 / 10F204
                
                cblock 0x10
                device.code     ; IR device code to send
                command.code    ; IR command code to send
                shift.temp      ; ir data temp shift register
                counter         ; count ir data bits shifted
                shift.count     ; count bits shifted
                endc

;***** NAME GPIO PORT BITS
S1              equ             1               ; GPIO 1                        
S2              equ             0               ; GPIO 0
S3              equ             3               ; GPIO 3
irled           equ             2               ; GPIO 2


;=====================================================================================
;
;  Program code starts here
;
;=====================================================================================
                ORG     0x000             ; processor reset vector

                ; Code in this section initialises the PIC
                ;
start           movwf   OSCCAL            ; update register with factory cal value 
                clrwdt

                ; options  1:256 prescaler to Tmr0, T0CS = Int Osc, Enable weak pull-ups
                ; Enable wake-on-change
                ; NB: This movlw instruction will clear the specifed bits in the option register  
                movlw           ~(1<<NOT_GPWU | 1<<NOT_GPPU | 1<<T0CS | 1<<PSA ) 
                option

                movlw            (1<<S1 | 1<<S2 | 1<<S3)        ; set switch I/O connect to input
                tris            GPIO

                ; initialise at start up
                bcf             GPIO, irled            ; turn off irled
                
;=====================================================================================
; Main code loop , scans keys, sends IR code as required or enters sleep is no key active

main            comf            GPIO,W                          ; invert value on GPIO and put in Wreg
                andlw           (1<<S1 | 1<<S2 | 1<<S3)         ; mask of all bits except the switch inputs
                skpz                                            ; if switches are all inactive skip next
                goto            tx.ir.code                      ; else at least one switch down so send ir data
                
                ; No switches active so PIC will enter sleep mode to reduce power to around 0.1uA
                bcf             GPIO, irled     ; turn off irled, should be off already but just make sure  
                sleep                           ; sleep
                ;
                ; Unlike the midrange PICs, the sleep instruction on the 10F2xx PICs
                ; doesn't wake up and start execution following the sleep instruction
                ; but instead it does a RESET.  Flag bits in the status register
                ; indicate the type of RESET, but for this application we don't care
                ; so the code just runs as if it was a power-on reset.
                ; See Microchip document TB082, Understanding Reset Events On The PIC10F20X

;=====================================================================================
; Test which key is pressed then generate 40Khz SIRC encoded PWM signal to drive IR LED.

tx.ir.code      movlw           C.device.id
                movwf           device.code     ; save as device code

                movlw           0xFF

                btfss           GPIO, S1        ; is switch 1 pressed
                movlw           C.cmd.S1        ; yes, load Wreg with SIRC cmd for S1

                btfss           GPIO, S2        ; is switch 2 pressed
                movlw           C.cmd.S2        ; yes, load Wreg with SIRC cmd for S2

                btfss           GPIO, S3        ; is switch 3 pressed
                movlw           C.cmd.S3        ; yes, load Wreg with SIRC cmd for S3

                movwf           command.code    ; save as command code
                incf            command.code,W  ; test if no key detected
                skpnz                           ; skip if key detected
                goto            main            ; else go back to sleep
                

;=====================================================================================
; SIRC transmission
                ; 2.4mS start
                ; 7 bit command
                ; 5 bit device
                ; 45mS repeat rate
                ; SIRC zero is represented by 600uS pulse
                ; SIRC one is represented by 1200uS pulse
                ; Each pulse is seperated with 600uS of idle time.
                ; Since the transmission time is variable dependant on the number of
                ; one's and zero's in the data, timer0 is started at the beginning 
                ; of the transmission with a 45mS period, the code then waits at the
                ; end of the data transmission for the timer to overflow.
                ; 12 bit SIRC is sent LSB first as shown below
                ; Start  Command   Device
                ;   S    0123456    01234

                movfw           command.code    ; copy command code into temporary bit shift register
                movwf           shift.temp

                movlw           (.256 - .45000 / .256)  ; load TMR0 for a 45mS timer period
                movwf           TMR0
 
                ; send 2400uS start
                call            do.2400uS       ; send 2400uS start pulse
                                
                ; send command word
                movlw           Ccmd.bit.length ; load counter with device bit length constant
                movwf           shift.count   
shift.cmd.loop  call            do.space        ; 600uS idle - no transmission
                rrf             shift.temp,F    ; shift next command bit into carry
                                                ; The delay functions don't affect the carry flag so 
                                                ; the following code works correctly..
                skpc                            ; skip if bit is a 1 - carry was set
                call            do.600uS        ; else send a 600uS zero pulse
                skpnc                           ; skip if bit is a 0 - carry was clear
                call            do.1200uS       ; else send a 1200uS one pulse  
                decfsz          shift.count,F   ; shift.count-- and skip next instruction if result is 0
                goto            shift.cmd.loop  ; else repeat for next bit of command word


                ; send device word.  Code functions same as command word above
                movfw           device.code     ; copy device code into temporary bit shift register
                movwf           shift.temp

                movlw           Cdev.bit.length ; load counter with command bit length constant
                movwf           shift.count  
shift.dev.loop  call            do.space   
                rrf             shift.temp,F  
                skpc                            
                call            do.600uS         
                skpnc                           
                call            do.1200uS       
                decfsz          shift.count,F              
                goto            shift.dev.loop  

                ; IR transmission are repeated at 45mS intervals.  Code waits here until 
                ; Timer0 overflows (==0) at the end of 45mS period.  Then go back and test
                ; switch inputs and either send another transmission or enter sleep mode.
                ; Timer0 must be polled since 10F20x PICs don't have interrrupt capability

                movfw           TMR0            ; load TMR0 into Wreg
                skpz                            ; if value is 0
                goto            $-2             ; go back two instructions
                goto            main            ; else go back to main

;-----------------------------------------------------------------
; pad the shift routines to generate 1200uS or 1800uS loop time
; this generates the 600uS space between ir signal burst
do.space        movlw           .73
                movwf           counter
loop.space      call            d4uS
                decfsz          counter,F
                goto            loop.space
                call            d5uS
                retlw 0x00

;-----------------------------------------------------------------
; 2400uS 40Khz burst with 30% duty cycle
do.2400uS       movlw           .98             ; count for a 2400uS burst
                goto            do.burst
; 1200uS 40Khz burst with 25% duty cycle
do.1200uS       movlw           .48             ; count for 1200uS burst
                goto            do.burst
; 600uS 40Khz burst with 25% duty cycle
do.600uS        movlw           .24             ; count for 600uS burst

do.burst        movwf           counter         ; load burst loop counter

                movlw           1<<irled        ; load W with data to turn on IR LED output

                ; duty cycle of 40Khz IR LED driver is ~25%
loop.burst      movwf           GPIO            ; LED on        1
                call            d5uS            ;               5
                clrf            GPIO            ; LED off       6
                call            d15uS           ;               21
                decfsz          counter,F       ;               22              
                goto            loop.burst      ;               24
                retlw 0x00
                
;-----------------------------------------------------------------
; micro second delays (timed from call to retlw 1<<rlled)
                                                ; delay
d15uS           nop                             ; 15
                goto            $+1             ; Waste 7uS, in the PIC16F version of this IR code
                goto            $+1             ; a call to d7uS was used, however the stack on the
                goto            $+1             ; 10F2xx parts is only 2 levels deep.  A call here would
                nop                             ; push a 3rd return address, causing it to overflow.
d7uS            goto            $+1             ; 7
d5uS            nop                             ; 5
d4uS            retlw           1<<irled        ; 4  Note: Code must return value for irled bit in W
                                                ; since this delay code is used in the loop.burst code
                                                ; which expects W to contain 1<<irled.
;
                
                dt "12 bit SIRC mini IR Transmitter V1.0 "
                dt "http://picprojects.org.uk "
                dt "(c) picprojects 2010 "

                end